[Plugin] Gorro de natal!

[Plugin] Gorro de natal!17/12/2013, 10:03 pm

Como está chegando o Natal, resolvi postar esse plugin.

Esse Plugin permite que você nasce no jogo com um gorro de natal para todos os players.
Não precisa comprar o gorro você já nasce com ele, caso queira retira-lo digite no SAY : /removergorro

IMAGEM:
[Plugin] Gorro de natal! MBNCYw3

SMA:

Código:

#include <  amxmodx >
#include <  engine >
#include <  cstrike >
#include <  hamsandwich >

#define CHAT_MSG "Voce Removeu seu Gorro de Natal!..."

new const g_szHatModel[ CsTeams ][ ] = {
    "",
    "models/santahat.mdl",
    "models/santahat_blue.mdl",
    ""
};

new g_iHats[ 33 ];

public plugin_init( ) {
    register_plugin( "Santa Hat + Snow", "1.3", "AMXX" );
    
    register_cvar( "santa_hat", "1.3", FCVAR_SERVER );
    
    register_event( "TeamInfo", "EventTeamInfo", "a" );
    
    register_clcmd( "say /removergorro", "remove_hat" ); 
    
    RegisterHam( Ham_Spawn, "player", "FwdHamPlayerSpawn", 1 );
}

public plugin_precache( ) {
//  create_entity( "env_snow" );
    
    precache_model( g_szHatModel[ CS_TEAM_T ] );
    precache_model( g_szHatModel[ CS_TEAM_CT ] );
}

public remove_hat( id )
{
    if( is_valid_ent( g_iHats[ id ] ) )
    {
        remove_entity( g_iHats[ id ] );
        client_print( id, print_chat, CHAT_MSG );
    }
    return PLUGIN_HANDLED;
}

public client_disconnect( id )
    if( is_valid_ent( g_iHats[ id ] ) )
        remove_entity( g_iHats[ id ] );

public FwdHamPlayerSpawn( const id ) {
    if( is_user_alive( id ) ) {
        new iEntity = g_iHats[ id ];
        
        if( !is_valid_ent( iEntity ) ) {
            if( !( iEntity = g_iHats[ id ] = create_entity( "info_target" ) ) )
                return;
            
            new CsTeams:iTeam = cs_get_user_team( id );
            
            if( iTeam != CS_TEAM_T && iTeam != CS_TEAM_CT )
                iTeam = CS_TEAM_T;
            
            entity_set_model( iEntity, g_szHatModel[ iTeam ] );
            entity_set_int( iEntity, EV_INT_movetype, MOVETYPE_FOLLOW );
            entity_set_edict( iEntity, EV_ENT_aiment, id );
        }
    }
}

public EventTeamInfo( ) {
    new id = read_data( 1 ), iEntity = g_iHats[ id ];
    
    if( !is_valid_ent( iEntity ) ) {
        if( iEntity > 0 )
            g_iHats[ id ] = 0;
        
        return;
    }
    
    new szTeam[ 2 ];
    read_data( 2, szTeam, 1 );
    
    if( szTeam[ 0 ] == 'C' )
        entity_set_model( iEntity, g_szHatModel[ CS_TEAM_CT ] );
    else
        entity_set_model( iEntity, g_szHatModel[ CS_TEAM_T ] );
}