[Ajuda] Nome Fundador, Master,Vip

5 participantes

[Ajuda] Nome Fundador, Master,Vip9/2/2013, 8:56 pm

To montando um addons e queria esse plugin, é aquele que quando o player escreve aparece no say.
[FUNDADOR] ...
[MASTER]...
[VIP]...

Mais queria ele configuradinho, se possivel a sma tbm. E como colocar na pasta users.ini os adms, vips, masters, etc....

Obrigado. Desde já.

Tags / Palavras chave: Ajuda

Re: [Ajuda] Nome Fundador, Master,Vip10/2/2013, 1:50 am

Código:

#include <   amxmodx >
#include <   amxmisc >

#define PLUGIN "say [master],[vip],[adm]"
#define VERSION "2.0"
#define AUTHOR "autor"

#define ADMIN_FUNDADOR_1 ADMIN_LEVEL_E // flag q
#define ADMIN_MASTER_2 ADMIN_LEVEL_F // flag r
#define ADMIN_ADM_3 ADMIN_LEVEL_G // flag s
#define ADMIN_VIP_4 ADMIN_LEVEL_H // flag t

new message[192]
new sayText
new teamInfo
new maxPlayers

new g_MessageColor
new g_NameColor
new g_AdminListen

new strName[191]
new strText[191]
new alive[11]

new const g_szTag[][] = 
{
   "",
   "[FUNDADOR]",
   "[MASTER]",
   "[ADM]",
   "[VIP]"
}

public plugin_init()
{
   register_plugin(PLUGIN, VERSION, AUTHOR)

   g_MessageColor = register_cvar("amx_color", "2") // Message colors: [1] Default Yellow, [2] Green, [3] White, [4] Blue, [5] Red
   g_NameColor = register_cvar("amx_namecolor", "6") // Name colors: [1] Default Yellow, [2] Green, [3] White, [4] Blue, [5] Red, [6] Team-color
   g_AdminListen = register_cvar("amx_listen", "1") // Set whether admins see or not all messages(Alive, dead and team-only)


   sayText = get_user_msgid("SayText")
   teamInfo = get_user_msgid("TeamInfo")
   maxPlayers = get_maxplayers()


   register_message(sayText, "avoid_duplicated")

   register_concmd("amx_color", "set_color", ADMIN_FUNDADOR_1, "<color>")
   register_concmd("amx_namecolor", "set_name_color", ADMIN_FUNDADOR_1, "<color>")
   register_concmd("amx_listen", "set_listen", ADMIN_FUNDADOR_1, "<1 | 0>")
   register_clcmd("say", "hook_say")
   register_clcmd("say_team", "hook_teamsay")
}


public avoid_duplicated(msgId, msgDest, receiver)
{
   return PLUGIN_HANDLED
}


public hook_say(id)
{
   read_args(message, 191)
   remove_quotes(message)

   // Gungame commands and empty messages
   if(message[0] == '@' || message[0] == '/' || message[0] == '!' || equal(message, "")) // Ignores Admin Hud Messages, Admin Slash commands,
      return PLUGIN_CONTINUE

   new name[32]
   get_user_name(id, name, 31)

   new admin = 0, iFlags = get_user_flags(id)

   if(iFlags & ADMIN_FUNDADOR_1)
      admin = 1
   else if(iFlags & ADMIN_MASTER_2)
      admin = 2
   else if(iFlags & ADMIN_ADM_3)
      admin = 3
   else if(iFlags & ADMIN_VIP_4)
      admin = 4

   new isAlive

   if(is_user_alive(id))
   {
      isAlive = 1
      alive = "^x01"
   }
   else
   {
      isAlive = 0
      alive = "^x01*DEAD* "
   }

   static color[10]

   if(admin)
   {
      // Name
      switch(get_pcvar_num(g_NameColor))
      {
         case 1:
            format(strName, 191, "^x04%s %s %s", g_szTag[admin], alive, name)
         case 2:
            format(strName, 191, "^x04%s %s^x04 %s ", g_szTag[admin], alive, name)
         case 3:
         {
            color = "SPECTATOR"
            format(strName, 191, "^x04%s %s^x03 %s ", g_szTag[admin], alive, name)
         }
         case 4:
         {
            color = "CT"
            format(strName, 191, "^x04%s %s^x03 %s", g_szTag[admin], alive, name)
         }
         case 5:
         {
            color = "TERRORIST"
            format(strName, 191, "^x04%s %s^x03 %s", g_szTag[admin], alive, name)
         }
         case 6:
         {
            get_user_team(id, color, 9)
            format(strName, 191, "^x04%s %s^x03 %s", g_szTag[admin], alive, name)
         }
      }

      // Message
      switch(get_pcvar_num(g_MessageColor))
      {
         case 1:    // Yellow
            format(strText, 191, "%s", message)
         case 2:    // Green
            format(strText, 191, "^x04%s", message)
         case 3:    // White
         {
            copy(color, 9, "SPECTATOR")
            format(strText, 191, "^x03%s", message)
         }
         case 4:    // Blue
         {
            copy(color, 9, "CT")
            format(strText, 191, "^x03%s", message)
         }
         case 5:    // Red
         {
            copy(color, 9, "TERRORIST")
            format(strText, 191, "^x03%s", message)
         }
      }
   }
   else     // Player is not admin. Team-color name : Yellow message
   {
      get_user_team(id, color, 9)
      format(strName, 191, "%s^x03 %s", alive, name)
      format(strText, 191, "%s", message)
   }

   format(message, 191, "%s^x01 : %s", strName, strText)

   sendMessage(color, isAlive)    // Sends the colored message

   return PLUGIN_CONTINUE
}


public hook_teamsay(id)
{
   new playerTeam = get_user_team(id)
   new playerTeamName[19]

   switch(playerTeam) // Team names which appear on team-only messages
   {
      case 1:
         copy(playerTeamName, 11, "Terrorists")

      case 2:
         copy(playerTeamName, 18, "Counter-Terrorists")

      default:
         copy(playerTeamName, 9, "Spectator")
   }

   read_args(message, 191)
   remove_quotes(message)

   // Gungame commands and empty messages
   if(message[0] == '@' || message[0] == '/' || message[0] == '!' || equal(message, "")) // Ignores Admin Hud Messages, Admin Slash commands,
      return PLUGIN_CONTINUE

   new name[32]
   get_user_name(id, name, 31)

   new admin = 0, iFlags = get_user_flags(id)

   if(iFlags & ADMIN_FUNDADOR_1)
      admin = 1
   else if(iFlags & ADMIN_MASTER_2)
      admin = 2
   else if(iFlags & ADMIN_ADM_3)
      admin = 3
   else if(iFlags & ADMIN_VIP_4)
      admin = 3

   new isAlive

   if(is_user_alive(id))
   {
      isAlive = 1
      alive = "^x01"
   }
   else
   {
      isAlive = 0
      alive = "^x01*DEAD* "
   }

   static color[10]

   if(admin)
   {
      // Name
      switch(get_pcvar_num(g_NameColor))
      {
         case 1:
            format(strName, 191, "%s(%s)^x04%s %s", alive, playerTeamName, g_szTag[admin], name)
         case 2:
            format(strName, 191, "%s(%s)^x04%s ^x04 %s", alive, playerTeamName, g_szTag[admin], name)
         case 3:
         {
            color = "SPECTATOR"
            format(strName, 191, "%s(%s)^x04%s ^x03 %s", alive, playerTeamName, g_szTag[admin], name)
         }
         case 4:
         {
            color = "CT"
            format(strName, 191, "%s(%s)^x04%s ^x03 %s", alive, playerTeamName, g_szTag[admin], name)
         }
         case 5:
         {
            color = "TERRORIST"
            format(strName, 191, "%s(%s)^x04%s ^x03 %s", alive, playerTeamName, g_szTag[admin], name)
         }
         case 6:
         {
            get_user_team(id, color, 9)
            format(strName, 191, "%s(%s)^x04%s ^x03 %s", alive, playerTeamName, g_szTag[admin], name)
         }
      }

      // Message
      switch(get_pcvar_num(g_MessageColor))
      {
         case 1:    // Yellow
            format(strText, 191, "%s", message)
         case 2:    // Green
            format(strText, 191, "^x04 %s", message)
         case 3:    // White
         {
            copy(color, 9, "SPECTATOR")
            format(strText, 191, "^x03 %s", message)
         }
         case 4:    // Blue
         {
            copy(color, 9, "CT")
            format(strText, 191, "^x03 %s", message)
         }
         case 5:    // Red
         {
            copy(color, 9, "TERRORIST")
            format(strText, 191, "^x03%s", message)
         }
      }
   }
   else     // Player is not admin. Team-color name : Yellow message
   {
      get_user_team(id, color, 9)
      format(strName, 191, "%s(%s) ^x03 %s", alive, playerTeamName, name)
      format(strText, 191, "%s", message)
   }

   format(message, 191, "%s ^x01 : %s", strName, strText)

   sendTeamMessage(color, isAlive, playerTeam)    // Sends the colored message

   return PLUGIN_CONTINUE
}


public set_color(id, level, cid)
{
   if(!cmd_access(id, level, cid, 2))
      return PLUGIN_HANDLED

   new arg[1], newColor
   read_argv(1, arg, 1)

   newColor = str_to_num(arg)

   if(newColor >= 1 && newColor <= 5)
   {
      set_pcvar_num(g_MessageColor, newColor)

      if(get_pcvar_num(g_NameColor) != 1 &&
         ((newColor == 3 &&  get_pcvar_num(g_NameColor) != 3)
         ||(newColor == 4 &&  get_pcvar_num(g_NameColor) != 4)
         ||(newColor == 5 &&  get_pcvar_num(g_NameColor) != 5)))
      {
         set_pcvar_num(g_NameColor, 2)
      }
   }

   return PLUGIN_HANDLED
}


public set_name_color(id, level, cid)
{
   if(!cmd_access(id, level, cid, 2))
      return PLUGIN_HANDLED

   new arg[1], newColor
   read_argv(1, arg, 1)

   newColor = str_to_num(arg)

   if(newColor >= 1 && newColor <= 6)
   {
      set_pcvar_num(g_NameColor, newColor)

      if((get_pcvar_num(g_MessageColor) != 1
         &&((newColor == 3 &&  get_pcvar_num(g_MessageColor) != 3)
         ||(newColor == 4 &&  get_pcvar_num(g_MessageColor) != 4)
         ||(newColor == 5 &&  get_pcvar_num(g_MessageColor) != 5)))
         || get_pcvar_num(g_NameColor) == 6)
      {
         set_pcvar_num(g_MessageColor, 2)
      }
   }

   return PLUGIN_HANDLED
}


public set_listen(id, level, cid)
{
   if(!cmd_access(id, level, cid, 2))
      return PLUGIN_HANDLED

   new arg[1], newListen
   read_argv(1, arg, 1)

   newListen = str_to_num(arg)

   set_pcvar_num(g_AdminListen, newListen)

   return PLUGIN_HANDLED
}


public sendMessage(color[], alive)
{
   new teamName[10]

   for(new player = 1; player < maxPlayers; player++)
   {
      if(!is_user_connected(player))
         continue

      if(alive && is_user_alive(player) || !alive && !is_user_alive(player) || get_pcvar_num(g_AdminListen) && get_user_flags(player) & ADMIN_FUNDADOR_1)
      {
         get_user_team(player, teamName, 9)    // Stores user's team name to change back after sending the message
         changeTeamInfo(player, color)        // Changes user's team according to color choosen
         writeMessage(player, message)        // Writes the message on player's chat
         changeTeamInfo(player, teamName)    // Changes user's team back to original
      }
   }
}


public sendTeamMessage(color[], alive, playerTeam)
{
   new teamName[10]

   for(new player = 1; player < maxPlayers; player++)
   {
      if(!is_user_connected(player))
         continue

      if(get_user_team(player) == playerTeam || get_pcvar_num(g_AdminListen) && get_user_flags(player) & ADMIN_FUNDADOR_1)
      {
         if(alive && is_user_alive(player) || !alive && !is_user_alive(player) || get_pcvar_num(g_AdminListen) && get_user_flags(player) & ADMIN_FUNDADOR_1)
         {
            get_user_team(player, teamName, 9)    // Stores user's team name to change back after sending the message
            changeTeamInfo(player, color)        // Changes user's team according to color choosen
            writeMessage(player, message)        // Writes the message on player's chat
            changeTeamInfo(player, teamName)    // Changes user's team back to original
         }
      }
   }
}


public changeTeamInfo(player, team[])
{
   message_begin(MSG_ONE, teamInfo, _, player)    // Tells to to modify teamInfo(Which is responsable for which time player is)
   write_byte(player)                // Write byte needed
   write_string(team)                // Changes player's team
   message_end()                    // Also Needed
}


public writeMessage(player, message[])
{
   message_begin(MSG_ONE, sayText, {0, 0, 0}, player)    // Tells to modify sayText(Which is responsable for writing colored messages)
   write_byte(player)                    // Write byte needed
   write_string(message)                    // Effectively write the message, finally, afterall
   message_end()                        // Needed as always
}

Re: [Ajuda] Nome Fundador, Master,Vip10/2/2013, 2:19 am

Obrigadooo *-* , Será que você teria a user.ini configuradinha pra me passar ai? :D obgg

Re: [Ajuda] Nome Fundador, Master,Vip17/3/2013, 2:44 am

Eu queria o download do plugin de colocar fundador

Re: [Ajuda] Nome Fundador, Master,Vip14/11/2013, 10:49 pm

aonde que add esse códigos sou novo comecei mexer com addons agora me ajudem

Re: [Ajuda] Nome Fundador, Master,Vip14/11/2013, 10:52 pm

http://adf.ly/246619/http://www.mediafire.com/download/mhwv3k26kmlbv9r/AdminPrefixes.rar. baixe isso e coloque no seu addons, dai você vai ver esses códigos

Re: [Ajuda] Nome Fundador, Master,Vip14/11/2013, 11:57 pm

vlw mano ajudo bastante

Re: [Ajuda] Nome Fundador, Master,Vip

Tópicos semelhantes

Ajuda Com tags fundador
Junin-pedido[fundador-master-adm-vip]
addons nao reconhece fundador master vip adm
[PEDIDO] ALGUEM ME PASSA O PLUGIN QUE TEM [FUNDADOR], [MASTER], [ADM], [VIP].
alguem sabe como adciona a steam de alguem pra master e fundador??

Ir para:

Permissões neste sub-fórum

Não podes responder a tópicos

Inicie sessão para responder

Seu portal de Zombie Plague no Brasil

[Ajuda] Nome Fundador, Master,Vip

description[Ajuda] Nome Fundador, Master,Vip9/2/2013, 8:56 pm

descriptionRe: [Ajuda] Nome Fundador, Master,Vip10/2/2013, 1:50 am

descriptionRe: [Ajuda] Nome Fundador, Master,Vip10/2/2013, 2:19 am

descriptionRe: [Ajuda] Nome Fundador, Master,Vip17/3/2013, 2:44 am

descriptionRe: [Ajuda] Nome Fundador, Master,Vip14/11/2013, 10:49 pm

descriptionRe: [Ajuda] Nome Fundador, Master,Vip14/11/2013, 10:52 pm

descriptionRe: [Ajuda] Nome Fundador, Master,Vip14/11/2013, 11:57 pm

descriptionRe: [Ajuda] Nome Fundador, Master,Vip